The MergeCells method combines two or more cells into one cell. The data in the first specified cell is displayed in the new larger cell. All the other cells' data is not lost. Use the CellMerge property to merge or unmerge a cell with another cell in the same item. Use the ItemDivider property to display a single cell in the entire item. Use the UnmergeCells method to unmerge the merged cells. Use the CellCaption property to specify the cell's caption. Use the ItemCell property to retrieves the handle of the cell. Use the BeginMethod and EndUpdate methods to maintain performance, when merging multiple cells in the same time. The MergeCells methods creates a list of cells from Cell1 and Cell2 parameters that need to be merged, and the first cell in the list specifies the displayed cell in the merged cell.

The following VB sample adds three columns to a group, a root item and few child items:

With ExplorerTree1
    .BeginUpdate
    With .Groups.Add("Group")
        .BeginUpdate
            .Expanded = True
            .AutoHeight = True
            .MarkSearchColumn = False
            .DrawGridLines = exAllLines
            .LinesAtRoot = exLinesAtRoot
            With .Columns.Item(0)
                .Def(exCellCaptionFormat) = exHTML
                .Width = 64
            End With
            .Columns.Add "Column 2"
            .Columns.Add "Column 3"
            .ColumnAutoResize = True
            With .Items
                Dim h As Long
                h = .AddItem("Root. This is the root item")
                .InsertItem h, , Array("Child 1", "SubItem 2", "SubItem 3")
                .InsertItem h, , Array("Child 2", "SubItem 2", "SubItem 3")
                .ExpandItem(h) = True
            End With
        .EndUpdate
    End With
    .EndUpdate
End With

(note that the caption of the root item is truncated by the column it belongs to)

If we are merging the first three cells in the root item we get:

The following VB sample merges the first three cells in the root item:

•  With ExplorerTree1.Groups(0)
      With .Items
          .CellMerge(.RootItem(0), 0) = Array(1, 2)
      End With
  End With

• With ExplorerTree1.Groups(0)
      .BeginUpdate
      With .Items
          Dim r As Long
          r = .RootItem(0)
          .CellMerge(r, 0) = 1
          .CellMerge(r, 0) = 2
      End With
      .EndUpdate
  End With

• With ExplorerTree1.Groups(0)
      .BeginUpdate
      With .Items
          Dim r As Long
          r = .RootItem(0)
          .MergeCells .ItemCell(r, 0), .ItemCell(r, 1)
          .MergeCells .ItemCell(r, 0), .ItemCell(r, 2)
      End With
      .EndUpdate
  End With

• With ExplorerTree1.Groups(0)
      With .Items
          Dim r As Long
          r = .RootItem(0)
          .MergeCells .ItemCell(r, 0), Array(.ItemCell(r, 1), .ItemCell(r, 2))
      End With
  End With

• With ExplorerTree1.Groups(0)
      With .Items
          Dim r As Long
          r = .RootItem(0)
          .MergeCells Array(.ItemCell(r, 0), .ItemCell(r, 1), .ItemCell(r, 2))
      End With
  End